| [作者] wonyen [头衔]
站长 [经验]
6019025 [等级]
大主帅 [发帖]
2789 [回帖]
1777 [登陆]
2388
[发表时间]
2005/10/26 21:04:34 [楼主]
|
|
| [作者]wonyen [头衔]站长 [经验]6019025 [等级]大主帅
[发帖]2789 [回帖]1777 [登陆]2388 [发表时间]2005/10/26 21:11:25 [1楼]
|
|
<%
function makefilename(fname)
fname = fname '前fname为变量，后fname为函数参数引用
fname = replace(fname,"-","")
fname = replace(fname," ","")
fname = replace(fname,":","")
fname = replace(fname,"PM","")
fname = replace(fname,"AM","")
fname = replace(fname,"上午","")
fname = replace(fname,"下午","")
makefilename = fname & ".html"
end function
%>
引用函数则：
<%fname = makefilename(now())%>
|
|
其实嘛，就是以年月日时分秒命名的文件。
iv，最后，生成的文件该如何查看到？当然需要把生成文件的路径保存的数据库中，并且添加到相对应的记录集中了。当然，这在下面的数据库设计时会提及到。
3，模板技术和2HTML技术的结合：将模板中特殊代码的值替换为从表单接受过来的值，完成模板功能；将最终替换过的所有模板代码生成HTML文件。需要注意的是：替换应能将输入数据的格式或者支持UBB的代码彻底改变。
二，再进行数据库设计
目前数据库的设计需要两个表：一个是存放模板数据的；一个是存放信息内容的。
1，建立新数据库asp2html.mdb
2，设计新数据库表c_moban
字段m_id（自动编号，主关键字）；字段m_html（备注类型）。
并将下列完整的代码拷贝至m_html字段
|
青青翠竹，无非正道；郁郁黄花，尽是真情
|
|
|
| [作者]wonyen [头衔]站长 [经验]6019025 [等级]大主帅
[发帖]2789 [回帖]1777 [登陆]2388 [发表时间]2005/10/26 21:20:46 [2楼]
|
|
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=hz">
<title>Cnbruce.Com | ASP2HTML TEST</title>
</head>
<body leftmargin="0" topmargin="0">
<table width="100%" height="100%" border="0" cellpadding="5" cellspacing="2">
<tr align="right" bgcolor="#CCCCCC">
<td height="20" colspan="2">$cntop$</td>
</tr>
<tr valign="top">
<td width="25%" bgcolor="#e5e5e5">$cnleft$</td>
<td width="74%" bgcolor="#f3f3f3">$cnright$</td>
</tr>
</table>
</body>
</html>
|
|
3，设计新数据库表c_news
字段c_id：自动编号，主关键字
字段c_title：文本类型，保存文章标题
字段c_content：备注类型，保存文章内容
字段c_filepath：文本类型，保持生成文件的路径地址
字段c_time：日期/时间类型，默认值：Now()
三，页面需求设计
1，首先建立一个存放HTML页的文件夹
在文件同一目录下，建立文件夹newsfile，夹子内部主要存放生成的HTML页面，当然内部还会采用程序方式建立以日期命名的子文件夹，以方便浏览以及管理。
2，功能函数页面lib.asp
|
青青翠竹，无非正道；郁郁黄花，尽是真情
|
|
|
| [作者]wonyen [头衔]站长 [经验]6019025 [等级]大主帅
[发帖]2789 [回帖]1777 [登陆]2388 [发表时间]2005/10/26 21:22:37 [3楼]
|
|
<%
'生成文件名的函数
function makefilename(fname)
fname = fname
fname = replace(fname,"-","")
fname = replace(fname," ","")
fname = replace(fname,":","")
fname = replace(fname,"PM","")
fname = replace(fname,"AM","")
fname = replace(fname,"上午","")
fname = replace(fname,"下午","")
makefilename=fname & ".shtml"
end function
'保持数据格式不变的函数
function HTMLEncode(fString)
fString = replace(fString, ">", ">")
fString = replace(fString, "<", "<")
fString = Replace(fString, CHR(32), " ")
fString = Replace(fString, CHR(13), "")
fString = Replace(fString, CHR(10) & CHR(10), "<br>")
fString = Replace(fString, CHR(10), "<br>")
HTMLEncode = fString
end function
%>
|
|
3，数据库连接页面conn.asp
完成数据库的字符串连接方法
|
青青翠竹，无非正道；郁郁黄花，尽是真情
|
|
|
| [作者]wonyen [头衔]站长 [经验]6019025 [等级]大主帅
[发帖]2789 [回帖]1777 [登陆]2388 [发表时间]2005/10/26 21:23:14 [4楼]
|
|
<%
set conn = Server.CreateObject("ADODB.Connection")
connstr = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&Server.MapPath("asp2html.mdb")
conn.Open connstr
%>
|
|
4，信息输入页面add.html
其实很简单：）就是表单嘛。注意action是跳转到addit.asp
<form action="addit.asp" method="post">
Title:<input type="text" name="c_title"><br>
Content:<br>
<textarea name="c_content" rows="8" cols="30"></textarea><br>
<input type="submit" value="Add">
<input type="reset" value="Reset">
</form>
5，处理数据功能显示页面addit.asp
首先是处理接受过来的数据，并将值写入数据库；接着将模板代码进行引用，并将其中特殊代码转换为接受值，最终通过FSO生成HTML页面。其中需要注意的还有，生成文件的路径地址保存至数据库表。
|
青青翠竹，无非正道；郁郁黄花，尽是真情
|
|
|
| [作者]wonyen [头衔]站长 [经验]6019025 [等级]大主帅
[发帖]2789 [回帖]1777 [登陆]2388 [发表时间]2005/10/26 21:24:17 [5楼]
|
|
<%'容错处理
On Error Resume Next
%>
<!--#include file="conn.asp" -->
<!--#include file="lib.asp" -->
<%'接受传递值
c_title=request.form("c_title")
c_content=request.form("c_content")
%>
<%'生成HTML文件名，建立文件夹，指定文件路径
fname = makefilename(now()) 'makefilename为自定义函数
folder = "newsfile/"&date()&"/"
filepath = folder&fname
%>
<%'将接受值及路径保持至数据库表
sql = "Select * from c_news"
Set rs = Server.CreateObject ("ADODB.Recordset")
rs.Open sql,conn,3,2
rs.addnew
rs("c_title")=c_title
rs("c_content")=c_content
rs("c_filepath")=filepath
rs.update
rs.close
Set rs = Nothing
%>
<%'打开模板代码，并将其中特殊代码转变为接受值
sql1="select m_id,m_html from c_moban where m_id=1"
set rs1=Server.CreateObject("adodb.recordset")
rs1.open sql1,conn,1,1
mb_code=rs1("m_html")
rs1.close
set rs1=nothing
conn.close
set conn=nothing
c_title=htmlencode(c_title)
c_content=htmlencode(c_content)
mb_code=replace(mb_code,"$cntop$",now())
mb_code=replace(mb_code,"$cnleft$",c_title)
mb_code=replace(mb_code,"$cnright$",c_content)
%>
<%'生成HTML页面
Set fso = Server.CreateObject("Scripting.FileSystemObject")
fso.CreateFolder(Server.MapPath(folder))
Set fout = fso.CreateTextFile(Server.MapPath(filepath))
fout.WriteLine mb_code
fout.close
%>
文章添加成功，<a href="showit.asp">浏览</a>
|
|
6，显示数据库表记录，并做指向HTML页的链接：showit.asp
[code]<!--#include file="conn.asp" -->
<!--#include file="lib.asp" -->
<%
Set rs = Server.CreateObject ("ADODB.Recordset")
sql = "Select * from c_news order by c_id desc"
rs.Open sql,conn,1,1
%>
<%
if rs.EOF and rs.BOF then
response.write ("暂时还没有文章，<a href=add.html>添加</a>")
else
Do Until rs.EOF
%>
<table width="758" border="0" align="center" cellpadding="3" cellspacing="1" bgcolor="#000000">
<tr>
<td width="159" align="right" bordercolor="#CCCCCC" bgcolor="#CCCCCC"><%=rs("c_time")%></td>
<td width="591" bordercolor="#f3f3f3" bgcolor="#f3f3f3"><a href=<%=rs("c_filepath")%> target="a_blank"><%=rs("c_title")%></a></td>
</tr>
<tr>
<td valign="top" align="right" bordercolor="#ececec" bgcolor="#ececec">[<a href=del.asp?c_id=<%=rs("c_id")%>>Dell</a>][<a href=change.asp?c_id=<%=rs("c_id")%>>Edit</a>][<a href="add.html">Add</a>]</td>
<td valign="top" bordercolor="#FFFFFF" bgcolor="#FFFFFF"><%=htmlencode(rs("c_content"))%></td>
</tr>
</table><br>
<%
rs.MoveNext
Loop
end if
%>
<%
rs.close
Set rs = Nothing
conn.close
set conn=Nothing
%>
[/code]
|
青青翠竹，无非正道；郁郁黄花，尽是真情
|
|
|
| [作者]wonyen [头衔]站长 [经验]6019025 [等级]大主帅
[发帖]2789 [回帖]1777 [登陆]2388 [发表时间]2005/10/26 21:25:13 [6楼]
|
|
7，修改数据内容页change.asp
修改数据内容，同时也需要修改更新对应的HTML页面。修改其实就是重新生成文件，且文件名和之前一样，类似文件的覆盖。
<!--#include file="conn.asp" -->
<!--#include file="lib.asp" -->
<%id=request.querystring("c_id")%>
<%
if request.form("submit")="change" then
c_title=request.form("c_title")
c_content=request.form("c_content")
c_id=request.form("c_id")
c_filepath=request.form("c_filepath")
Set rs = Server.CreateObject ("ADODB.Recordset")
sql = "Select * from c_news where c_id="&c_id
rs.Open sql,conn,3,2
rs("c_title")=c_title
rs("c_content")=c_content
rs("c_time")=now()
rs.update
rs.close
Set rs = Nothing
%>
<%'打开模板代码，并将其中特殊代码转变为接受值
sql1="select m_id,m_html from c_moban where m_id=1"
set rs1=Server.CreateObject("adodb.recordset")
rs1.open sql1,conn,1,1
mb_code=rs1("m_html")
rs1.close
set rs1=nothing
conn.close
set conn=nothing
c_title=htmlencode(c_title)
c_content=htmlencode(c_content)
mb_code=replace(mb_code,"$cntop$",now())
mb_code=replace(mb_code,"$cnleft$",c_title)
mb_code=replace(mb_code,"$cnright$",c_content)
%>
<%'生成HTML页面
Set fso = Server.CreateObject("Scripting.FileSystemObject")
Set fout = fso.CreateTextFile(Server.MapPath(c_filepath))
fout.WriteLine mb_code
fout.close
%>
<%response.redirect("showit.asp")%>
<%end if%>
<%
if id<>"" then
Set rs = Server.CreateObject ("ADODB.Recordset")
sql="select * from c_news where c_id="&id
rs.Open sql,conn,1,1
c_id=rs("c_id")
c_filepath=rs("c_filepath")
c_title=rs("c_title")
c_content=rs("c_content")
end if
%>
<form action="change.asp" method="post">
Title:<input type="text" name="c_title" value=<%=c_title%>><br>
Content:<br>
<textarea name="c_content" rows="8" cols="30"><%=c_content%></textarea><br>
<input type="submit" value="change" name="submit">
<input type="reset" value="Reset">
<input name="c_id" type="hidden" value="<%=id%>">
<input name="c_filepath" type="hidden" value="<%=c_filepath%>">
</form>
|
青青翠竹，无非正道；郁郁黄花，尽是真情
|
|
|
| [作者]wonyen [头衔]站长 [经验]6019025 [等级]大主帅
[发帖]2789 [回帖]1777 [登陆]2388 [发表时间]2005/10/26 21:28:20 [7楼]
|
|
|
|
|